Populate repo

zsh/.oh-my-zsh/plugins/timer/README.md

@@ -0,0 +1,18 @@
+This plugin allows to display command's execution time in a very nonintrusive way.
+
+Timer can be tuned by these two variables:
+* `TIMER_PRECISION` allows to control number of decimal places (default `1`)
+* `TIMER_FORMAT` allows to adjust display format (default `'/%d'`)
+* `TIMER_THRESHOLD` allows to set the minimum execution time that causes the timer to be shown (default `0`)
+
+Sample session:
+
+    me@here:~$ sleep 1                                         /1.0s
+    me@here:~$ sleep 73                                     /1m13.0s
+    me@here:~$ TIMER_FORMAT='[%d]'; TIMER_PRECISION=2        [0.00s]
+    me@here:~$ head -c50 < /dev/urandom | hexdump
+    0000000 b2 16 20 f0 29 1f 61 2d 8a 29 20 8c 8c 39 5a ab
+    0000010 21 47 0e f9 ee a4 76 46 71 9e 4f 6b a4 c4 51 cb
+    0000020 f9 1f 7e b9 6f 2c ae dd cf 40 6d 64 a8 fb d3 db
+    0000030 09 37
+    0000032                                                  [0.02s]

zsh/.oh-my-zsh/plugins/timer/timer.plugin.zsh

@@ -0,0 +1,35 @@
+zmodload zsh/datetime
+
+__timer_current_time() {
+  zmodload zsh/datetime
+  echo $EPOCHREALTIME
+}
+
+__timer_format_duration() {
+  local mins=$(printf '%.0f' $(($1 / 60)))
+  local secs=$(printf "%.${TIMER_PRECISION:-1}f" $(($1 - 60 * mins)))
+  local duration_str=$(echo "${mins}m${secs}s")
+  local format="${TIMER_FORMAT:-/%d}"
+  echo "${format//\%d/${duration_str#0m}}"
+}
+
+__timer_save_time_preexec() {
+  __timer_cmd_start_time=$(__timer_current_time)
+}
+
+__timer_display_timer_precmd() {
+  if [ -n "${__timer_cmd_start_time}" ]; then
+    local cmd_end_time=$(__timer_current_time)
+    local tdiff=$((cmd_end_time - __timer_cmd_start_time))
+    unset __timer_cmd_start_time
+    if [[ -z "${TIMER_THRESHOLD}" || ${tdiff} -ge "${TIMER_THRESHOLD}" ]]; then
+        local tdiffstr=$(__timer_format_duration ${tdiff})
+        local cols=$((COLUMNS - ${#tdiffstr} - 1))
+        echo -e "\033[1A\033[${cols}C ${tdiffstr}"
+    fi
+  fi
+}
+
+autoload -U add-zsh-hook
+add-zsh-hook preexec __timer_save_time_preexec
+add-zsh-hook precmd __timer_display_timer_precmd